%% This file, part of the Makor2 system for typesetting Hebrew with Omega,
%% generates the archaic Palestinian vowels for Hebrew.

mode_setup;
designsize:=10pt#;
if unknown FontSize: FontSize := 10pt#; fi
FX# := FontSize *   0.075 / 2.4; % normalize to 10pt---AH
FY# := FontSize *   0.075 / 2.4;
%% At 10ot, FX#=FY#=.3125pt.
define_pixels (FX, FY);

mynib#:=3FX#;
define_pixels (mynib);
def picknib=pickup pencircle scaled mynib enddef;

%% no sheva vowel...

beginchar(72, mynib#, 4.5mynib#,0); % qamats
  x0=x1=.5w; y0=0; y1=h;
  pickup penrazor xscaled mynib yscaled 0;
  draw z0--z1;
endchar;

beginchar(71, 10FX#, mynib#,0); % patah
  z0=(0,h/2); z1=(w,y0);
  pickup penrazor xscaled h yscaled 0 rotated 90;
  draw z0--z1;
endchar;

beginchar(69, 3mynib#, 3mynib#,0); % tsere
  x0=.5mynib; y0=h-.5mynib; x1=w-.5mynib; y1+y0=h;
  picknib; drawdot z0; drawdot z1;
endchar;

beginchar(68, mynib#, mynib#, 0); % hiriq
  z0=(.5w,.5h); picknib; drawdot z0;
endchar;

beginchar(73, 3mynib#, 3mynib#, 0); % holam
  x0=.5mynib; x0+x1=w; y0=y1=.5mynib;
  x2=.5w; y2+y0=h; picknib;
  drawdot z0; drawdot z1; drawdot z2;
endchar;

beginchar(182, 3mynib#, mynib#,0); % meteg hiriq
  x0=y0=.5w; x1=x0; y0+y1=h; picknib;
  drawdot z0; drawdot z1;
endchar;

beginchar(75, 3mynib#, mynib#, 0); % qubuts
  z0=(.5mynib, h/2); z1=(w-x0, y0); picknib;
  drawdot z0; drawdot z1;
endchar;

beginchar(70, 3mynib#, 3mynib#,0); % segol
  x0=y0=.5mynib; x0+x1=w; y0+y1=h;
  picknib; drawdot z0; drawdot z1;
endchar;

bye.